home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / file.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  19.4 KB  |  962 lines
  1. ;
  2. ; file.s -- an ACE linked library module: file functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd-30th November, 1st-13th December 1991,
  21. ;      20th, 23rd,25th-27th January 1992, 
  22. ;         2nd,4th,6th,12th-19th,21st-24th,29th February 1992,
  23. ;      1st,14th March 1992,
  24. ;      4th,7th,21st,22nd,26th April 1992,
  25. ;      2nd,3rd,5th,7th,8th,10th-17th May 1992,
  26. ;      6th,8th,11th,12th,28th,30th June 1992,
  27. ;      1st-3rd,13th,14th,18th-20th,22nd July 1992,
  28. ;      9th August 1992,
  29. ;      5th,21st December 1992,
  30. ;      5th,6th,12th January 1993,
  31. ;      7th,14th-16th,18th February 1993,
  32. ;      1st March 1993,
  33. ;      9th-11th May 1993,
  34. ;      10th June 1993,
  35. ;      26th September 1993,
  36. ;      19th March 1994,
  37. ;      10th April 1994,
  38. ;      13th May 1994,
  39. ;      10th,15th,17th March 1996
  40. ;
  41. ; registers d0-d6 and a0-a3 are modified by some of the following. BEWARE!
  42. ;
  43. ; a4,a5 are used by link/unlk.
  44. ; a6 is library base holder.
  45. ; a7 is stack pointer. 
  46. ; d7 is used for array index calculations.
  47. ;
  48.  
  49. ; error codes
  50. BFN    equ    52    ; Bad File Number
  51. BFM    equ    54    ; Bad File Mode
  52.  
  53. ; miscellaneous defines
  54. MAXSTRINGSIZE         equ     1024
  55. OFFSET_END        equ    1
  56. OFFSET_BEGINNING    equ    -1
  57. MODE_OLDFILE        equ    1005
  58. MODE_NEWFILE        equ    1006
  59. MODE_READWRITE        equ    1004
  60. ACCESS_READ        equ    -2    
  61.  
  62.     ; file routines
  63.     xdef    _openfile
  64.     xdef    _closefile
  65.  
  66.     xdef    _writeshort
  67.     xdef    _writelong
  68.     xdef    _writesingle
  69.     xdef    _writestring    ; WRITE# / PRINT#
  70.  
  71.     xdef    _fprintshort
  72.     xdef    _fprintlong
  73.     xdef    _fprintsingle    ; PRINT#
  74.  
  75.     xdef    _writecomma
  76.     xdef    _writequote
  77.     xdef    _write_eoln
  78.     xdef    _writeSPC
  79.     xdef    _writeTAB    ; WRITE# / PRINT# 
  80.  
  81.     xdef    _inputstrfromfile
  82.     xdef    _line_input
  83.  
  84.     xdef    _finputstring
  85.     xdef    _finputsingle
  86.     xdef    _finputshort
  87.     xdef    _finputlong    ; INPUT#
  88.  
  89.     xdef    _eoftest
  90.     xdef    _lof
  91.     xdef    _handle
  92.  
  93.     xdef    _kill
  94.     xdef    _rename
  95.     xdef    _chdir
  96.  
  97.        ; external references
  98.     xref    _shortfmt
  99.     xref    _longfmt
  100.     xref    _file_handle_list
  101.     xref    _line_end
  102.     xref    _quote_mark
  103.     xref    _comma
  104.     xref    _space
  105.     xref    _tab
  106.  
  107.     xref    _fileinpstring
  108.     xref    _filecharcount
  109.     xref    _tempfinp
  110.     xref    _fstrbuf
  111.     xref    _filenum
  112.     xref    _eofhandle
  113.     xref    _filesize
  114.     xref    _filehandle
  115.     xref    _oldfilepos
  116.     xref    _filespec_ptr
  117.  
  118.     xref    _error_code
  119.  
  120.     xref    _strlen
  121.     xref    _sprintf
  122.     xref    _fgetchars
  123.     xref    _fgetline
  124.     xref    _fgetseqfld
  125.     xref    _strshort
  126.     xref    _strlong
  127.     xref    _strsingle
  128.     xref    _val
  129.     xref    _short_from_string
  130.     xref    _long_from_string
  131.        xref      _LVOWrite
  132.     xref    _LVORead
  133.     xref    _LVOOpen
  134.     xref    _LVOClose
  135.     xref    _LVOSeek
  136.     xref    _LVODeleteFile
  137.     xref    _LVORename
  138.     xref    _LVOLock
  139.     xref    _LVOUnLock
  140.     xref    _LVOCurrentDir
  141.     xref    _LVOIoErr
  142.  
  143.       xref      _DOSBase    
  144.  
  145.     SECTION file_code,CODE
  146.  
  147. ; *** FILE ROUTINES ***
  148.  
  149. ;
  150. ; Ask DOS whether an error has occurred since the last I/O operation.
  151. ;
  152. _IoErr_poll:
  153.     move.l    d0,-(sp)
  154.  
  155.     cmpi.l    #0,d0
  156.     bgt.s    _quit_IoErr_poll  ; Last operation was successful
  157.  
  158.     ; Last operation was unsuccessful -> get error code
  159.     movea.l    _DOSBase,a6
  160.     jsr    _LVOIoErr(a6)
  161.     move.l    d0,_error_code
  162.  
  163. _quit_IoErr_poll:    
  164.     move.l    (sp)+,d0
  165.     rts
  166.  
  167. ;
  168. ; OPEN mode,[#]filenumber,filespec - open a file. 
  169. ;                   - a0=mode string; d0=filenumber; 
  170. ;                     a1=filespec string.
  171. ;
  172. _openfile:
  173.     jsr    _gencheckfilenum
  174.     cmpi.l    #-1,d0
  175.     bne.s    _get_filehandle
  176.     moveq    #0,d0
  177.     rts
  178.  
  179. _get_filehandle:
  180.     lsl.l    #2,d0        ; filenumber x 4.        
  181.     move.l    #_file_handle_list,d4
  182.     add.l    d0,d4        ; find start of long in list
  183.     move.l    d4,a3
  184.     cmpi.l    #0,(a3)
  185.     beq.s    _whichopenmode    ; if file handle not used -> continue
  186.  
  187.     move.l    #BFN,_error_code
  188.  
  189.     rts
  190.  
  191. _whichopenmode:
  192.     ; determine open mode
  193.     cmpi.b    #79,(a0)    ; "O" ?
  194.     beq.s    _openforoutput
  195.     cmpi.b    #111,(a0)    ; "o" ?
  196.     beq.s    _openforoutput
  197.     
  198.     cmpi.b    #73,(a0)    ; "I" ?
  199.     beq.s    _openforinput
  200.     cmpi.b    #105,(a0)    ; "i" ?
  201.     beq.s    _openforinput
  202.  
  203.      cmpi.b    #82,(a0)    ; "R" ?
  204.     beq.s    _openforrandom
  205.      cmpi.b    #114,(a0)    ; "r" ?
  206.     beq.s    _openforrandom
  207.  
  208.      cmpi.b    #65,(a0)    ; "A" ?
  209.     beq.s    _openforappend
  210.      cmpi.b    #97,(a0)    ; "a" ?
  211.     beq.s    _openforappend
  212.  
  213.     move.l    #BFM,_error_code
  214.  
  215.     rts
  216.  
  217. _openforoutput:
  218.     move.l    _DOSBase,a6
  219.     move.l    a1,d1            ; filespec
  220.     move.l    #MODE_NEWFILE,d2    ; create a new file
  221.     jsr    _LVOOpen(a6)
  222.     move.l    d0,(a3)            ; store file handle
  223.     jsr    _IoErr_poll
  224.     rts
  225.  
  226. _openforinput:
  227.     move.l    _DOSBase,a6
  228.     move.l    a1,d1            ; filespec
  229.     move.l    #MODE_OLDFILE,d2    ; open an existing file
  230.     jsr    _LVOOpen(a6)
  231.     move.l    d0,(a3)            ; store file handle
  232.     jsr    _IoErr_poll
  233.     rts
  234.  
  235. _openforrandom:
  236.     move.l    _DOSBase,a6
  237.     move.l    a1,d1            ; filespec
  238.     move.l    #MODE_READWRITE,d2    ; create a new file
  239.     jsr    _LVOOpen(a6)
  240.     move.l    d0,(a3)            ; store file handle
  241.     jsr    _IoErr_poll
  242.     rts
  243.  
  244. _openforappend:
  245.     move.l    _DOSBase,a6
  246.  
  247.     move.l    a1,_filespec_ptr    ; save filespec pointer
  248.  
  249.     move.l    a1,d1            ; filespec
  250.     move.l    #MODE_OLDFILE,d2    ; Test whether file exists
  251.     jsr    _LVOOpen(a6)
  252.     move.l    d0,(a3)            ; store file handle
  253.     
  254.     cmpi.l    #0,d0            ; if handle = NULL then  
  255.     bne.s    _seek_to_end_of_file    ; open a new file first
  256.                     ; else just seek to end 
  257.                     ; of existing file + 1 byte.
  258.  
  259.     move.l    _filespec_ptr,d1    ; filespec
  260.     move.l    #MODE_NEWFILE,d2    ; Create a new file    
  261.     jsr    _LVOOpen(a6)
  262.     move.l    d0,(a3)            ; store file handle
  263.     jsr    _IoErr_poll
  264.     
  265.     rts
  266.     
  267. _seek_to_end_of_file:
  268.     ; set file pointer to EOF
  269.     move.l    d0,d1            ; file handle
  270.     move.l    #0,d2            ; position=0 bytes from end
  271.     move.l    #1,d3            ; offset from end
  272.     jsr    _LVOSeek(a6)
  273.     jsr    _IoErr_poll
  274.  
  275.     rts
  276.         
  277. ;
  278. ; CLOSE [#]filenumber[,[#]filenumber..] - close a file. d0=filenumber.
  279. ;
  280. _closefile:
  281.     jsr    _gencheckfilenum
  282.     cmpi.l    #-1,d0
  283.     bne.s    _closefile_gethandlestore
  284.     moveq    #0,d0
  285.     rts
  286.  
  287. _closefile_gethandlestore:
  288.     lsl.l    #2,d0        ; filenumber x 4.        
  289.     move.l    #_file_handle_list,d4
  290.     add.l    d0,d4        ; find start of long in list
  291.     move.l    d4,a3
  292.     cmpi.l    #0,(a3)
  293.     bne.s    _close_the_file    ; if file handle is used -> continue
  294.     move.l    #BFN,_error_code
  295.     rts
  296.  
  297. _close_the_file:
  298.     movea.l    _DOSBase,a6
  299.     move.l    (a3),d1        ; file handle
  300.     jsr    _LVOClose(a6)
  301.  
  302.     ; zero the filehandle
  303.     move.l    #0,(a3)
  304.  
  305.     rts
  306.  
  307. ;
  308. ; write a short integer to a file. d0=filenumber. d1=short integer.
  309. ;
  310. _writeshort:
  311.     move.l    d0,_filenum    ; save filenumber
  312.  
  313.     ; convert short to a string
  314.     move.w    d1,-(sp)
  315.     pea    _shortfmt
  316.     move.l    #_fstrbuf,-(sp)
  317.     jsr    _sprintf
  318.     add.l    #10,sp
  319.  
  320.     lea    _fstrbuf,a0
  321.     move.l    _filenum,d0
  322.     jsr    _writestring    ; write to file
  323.  
  324.     rts
  325.  
  326. ;
  327. ; write a long integer to a file. d0=filenumber; d1=long integer.
  328. ;
  329. _writelong:
  330.     move.l    d0,_filenum    ; save filenumber
  331.  
  332.     ; convert long to a string
  333.     move.l    d1,-(sp)
  334.     pea    _longfmt
  335.     move.l    #_fstrbuf,-(sp)
  336.     jsr    _sprintf
  337.     add.l    #12,sp
  338.  
  339.     lea    _fstrbuf,a0
  340.     move.l    _filenum,d0
  341.     jsr    _writestring    ; write to file
  342.  
  343.     rts
  344.  
  345. ;
  346. ; write a single-precision value to a file. d0=filenumber; d1=FFP value.
  347. ;
  348. _writesingle:
  349.     move.l    d0,_filenum    ; save filenumber
  350.  
  351.     ; convert FFP to a string
  352.     move.l    d1,-(sp)    ; FFP value    
  353.     jsr    _strsingle
  354.     addq    #4,sp
  355.     move.l    d0,a0        ; fnumbuf string address        
  356.  
  357.     cmpi.b    #32,(a0)
  358.     bne.s    _write_ffp_str
  359.     adda.l    #1,a0        ; if ffp string starts with space -> ignore it
  360.  
  361. _write_ffp_str:
  362.     move.l    _filenum,d0    ; d0=filenumber; a0=string
  363.     jsr    _writestring    ; write to file
  364.  
  365.     rts
  366.  
  367. ;
  368. ; PRINT # - write a short integer to a file. d0=short integer; d1=filenumber. 
  369. ;
  370. _fprintshort:
  371.     ; save filenumber.
  372.     move.l    d1,_filenum
  373.     
  374.     ; convert short to string +/- leading space.
  375.     lea    _fstrbuf,a0
  376.     jsr    _strshort    ; a0=string.
  377.  
  378.     ; write the string: d0=filenumber; a0=string.
  379.     move.l    _filenum,d0    
  380.     jsr    _writestring
  381.  
  382.     rts
  383.  
  384. ;
  385. ; PRINT # - write a long integer to a file. d0=long integer; d1=filenumber. 
  386. ;
  387. _fprintlong:
  388.     ; save filenumber.
  389.     move.l    d1,_filenum
  390.     
  391.     ; convert long to string +/- leading space.
  392.     lea    _fstrbuf,a0
  393.     jsr    _strlong    ; a0=string.
  394.  
  395.     ; write the string: d0=filenumber; a0=string.
  396.     move.l    _filenum,d0    
  397.     jsr    _writestring
  398.  
  399.     rts
  400.  
  401. ;
  402. ; PRINT # - write a FFP value to a file. d0=FFP value; d1=filenumber. 
  403. ;
  404. _fprintsingle:
  405.     ; save filenumber.
  406.     move.l    d1,_filenum
  407.     
  408.     ; convert FFP to string +/- leading space.
  409.     move.l    d0,-(sp)
  410.     jsr    _strsingle    ; a0=string.
  411.     addq    #4,sp
  412.     move.l    d0,a0
  413.  
  414.     ; write the string: d0=filenumber; a0=string.
  415.     move.l    _filenum,d0    
  416.     jsr    _writestring
  417.  
  418.     rts
  419.         
  420. ;
  421. ; write a string to a file. d0=filenumber; a0=string.
  422. ;
  423. _writestring:
  424.     jsr    _gencheckfilenum
  425.     cmpi.l    #-1,d0
  426.     bne.s    _writestring_gethandlestore
  427.     moveq    #0,d0        
  428.     rts
  429.  
  430. _writestring_gethandlestore:
  431.     lsl.l    #2,d0        ; filenumber x 4.        
  432.     move.l    #_file_handle_list,d4
  433.     add.l    d0,d4          ; find start of long in list
  434.     move.l    d4,a3
  435.     cmpi.l    #0,(a3)
  436.     bne.s    _write_the_string ; if file handle is used -> continue
  437.     move.l    #BFN,_error_code
  438.     rts
  439.  
  440. _write_the_string:
  441.     move.l    _DOSBase,a6
  442.     move.l    (a3),d1        ; file handle
  443.     move.l    a0,d2        ; string address
  444.     move.l    a0,a2
  445.     jsr    _strlen
  446.     cmpi.l    #0,d0
  447.     bne.s    _do_writestring
  448.     addq.l    #1,d0        ; allow CHR$(0)!!! (some prgs use this)
  449. _do_writestring:
  450.     move.l    d0,d3        ; length of string
  451.     jsr    _LVOWrite(a6)
  452.     jsr    _IoErr_poll
  453.     
  454.     rts
  455.  
  456. ;
  457. ; write a comma to delimit items. d0=filenumber. 
  458. ;
  459. _writecomma:
  460.     jsr    _gencheckfilenum
  461.     cmpi.l    #-1,d0
  462.     bne.s    _writecomma_gethandlestore
  463.     moveq    #0,d0
  464.     rts
  465.  
  466. _writecomma_gethandlestore:
  467.     lsl.l    #2,d0        ; filenumber x 4.        
  468.     move.l    #_file_handle_list,d4
  469.     add.l    d0,d4        ; find start of long in list
  470.     move.l    d4,a3
  471.     cmpi.l    #0,(a3)
  472.     bne.s    _write_the_comma ; if file handle is used -> continue
  473.     move.l    #BFN,_error_code
  474.     rts
  475.  
  476. _write_the_comma:
  477.     move.l    _DOSBase,a6
  478.     move.l    (a3),d1        ; file handle
  479.     move.l    #_comma,d2    ; string address
  480.     moveq    #1,d3        ; length of string
  481.     jsr    _LVOWrite(a6)
  482.     jsr    _IoErr_poll
  483.         
  484.     rts
  485.  
  486. ;
  487. ; write a quotation mark (") to a file to signal the start or end of a string. 
  488. ; d0=filenumber. 
  489. ;
  490. _writequote:
  491.     jsr    _gencheckfilenum
  492.     cmpi.l    #-1,d0
  493.     bne.s    _writequote_gethandlestore
  494.     moveq    #0,d0
  495.     rts
  496.  
  497. _writequote_gethandlestore:
  498.     lsl.l    #2,d0        ; filenumber x 4.        
  499.     move.l    #_file_handle_list,d4
  500.     add.l    d0,d4        ; find start of long in list
  501.     move.l    d4,a3
  502.     cmpi.l    #0,(a3)
  503.     bne.s    _write_the_quote ; if file handle is used -> continue
  504.     move.l    #BFN,_error_code
  505.     rts
  506.  
  507. _write_the_quote:
  508.     move.l    _DOSBase,a6
  509.     move.l    (a3),d1        ; file handle
  510.     move.l    #_quote_mark,d2    ; string address
  511.     moveq    #1,d3        ; length of string
  512.     jsr    _LVOWrite(a6)
  513.     jsr    _IoErr_poll
  514.         
  515.     rts
  516.  
  517. ;
  518. ; write a LF to a file to signal eoln. d0=filenumber. 
  519. ;
  520. _write_eoln:
  521.     jsr    _gencheckfilenum
  522.     cmpi.l    #-1,d0
  523.     bne.s    _write_eoln_gethandlestore
  524.     moveq    #0,d0
  525.     rts
  526.  
  527. _write_eoln_gethandlestore:
  528.     lsl.l    #2,d0        ; filenumber x 4.        
  529.     move.l    #_file_handle_list,d4
  530.     add.l    d0,d4         ; find start of long in list
  531.     move.l    d4,a3
  532.     cmpi.l    #0,(a3)
  533.     bne.s    _write_the_eoln  ; if file handle is used -> continue
  534.     move.l    #BFN,_error_code
  535.     rts
  536.  
  537. _write_the_eoln:
  538.     move.l    _DOSBase,a6
  539.     move.l    (a3),d1        ; file handle
  540.     move.l    #_line_end,d2    ; string address
  541.     move.l    #1,d3        ; length of string
  542.     jsr    _LVOWrite(a6)
  543.     jsr    _IoErr_poll
  544.         
  545.     rts
  546.  
  547. ;
  548. ; write a space to a file. d0=filenumber. 
  549. ;
  550. _writeSPC:
  551.     jsr    _gencheckfilenum
  552.     cmpi.l    #-1,d0
  553.     bne.s    _writeSPC_gethandlestore
  554.     moveq    #0,d0
  555.     rts
  556.  
  557. _writeSPC_gethandlestore:
  558.     lsl.l    #2,d0        ; filenumber x 4.        
  559.     move.l    #_file_handle_list,d4
  560.     add.l    d0,d4        ; find start of long in list
  561.     move.l    d4,a3
  562.     cmpi.l    #0,(a3)
  563.     bne.s    _write_the_SPC ; if file handle is used -> continue
  564.     move.l    #BFN,_error_code
  565.     rts
  566.  
  567. _write_the_SPC:
  568.     move.l    _DOSBase,a6
  569.     move.l    (a3),d1        ; file handle
  570.     move.l    #_space,d2    ; string address
  571.     moveq    #1,d3        ; length of string
  572.     jsr    _LVOWrite(a6)
  573.     jsr    _IoErr_poll
  574.         
  575.     rts
  576.  
  577. ;
  578. ; write a TAB to a file. d0=filenumber. 
  579. ;
  580. _writeTAB:
  581.     jsr    _gencheckfilenum
  582.     cmpi.l    #-1,d0
  583.     bne.s    _writeTAB_gethandlestore
  584.     moveq    #0,d0
  585.     rts
  586.  
  587. _writeTAB_gethandlestore:
  588.     lsl.l    #2,d0        ; filenumber x 4.        
  589.     move.l    #_file_handle_list,d4
  590.     add.l    d0,d4        ; find start of long in list
  591.     move.l    d4,a3
  592.     cmpi.l    #0,(a3)
  593.     bne.s    _write_the_TAB ; if file handle is used -> continue
  594.     move.l    #BFN,_error_code
  595.     rts
  596.  
  597. _write_the_TAB:
  598.     move.l    _DOSBase,a6
  599.     move.l    (a3),d1        ; file handle
  600.     move.l    #_tab,d2    ; string address
  601.     moveq    #2,d3        ; length of string
  602.     jsr    _LVOWrite(a6)
  603.     jsr    _IoErr_poll
  604.         
  605.     rts
  606.  
  607. ;
  608. ; INPUT$(X,[#]filenumber) - input X characters from a file.
  609. ;              - d1=X, d0=filenumber.
  610. ;
  611. _inputstrfromfile:
  612.     ; get address of buffer.
  613.     lea    _fileinpstring,a0    ; this means a 32K limit!!!
  614.  
  615.     ; ++d1 -> fgetchars() returns n-1 characters.
  616.     addq    #1,d1
  617.  
  618.     ; is X reasonable (ie: X > 0) ?
  619.     ; (X should have no upper limit since INPUT$ 
  620.     ;  may be used to read a whole file).
  621.     cmpi.l    #0,d1
  622.     bgt.s    _filenumcheck_inputstrfromfile    
  623.  
  624.     move.b    #0,(a0)
  625.     rts                ; X <= 0? -> return NULL string.
  626.  
  627. _filenumcheck_inputstrfromfile:
  628.     ; legal file number?
  629.     jsr    _gencheckfilenum
  630.     cmpi.l    #-1,d0
  631.     bne.s    _inputstrfromfile_get_handle
  632.  
  633.     move.b    #0,(a0)
  634.     rts                ; return NULL string.
  635.  
  636. _inputstrfromfile_get_handle:
  637.     lsl.l    #2,d0            ; filenumber x 4.        
  638.     move.l    #_file_handle_list,d4
  639.     add.l    d0,d4             ; find start of long in list.
  640.     move.l    d4,a3
  641.     cmpi.l    #0,(a3)
  642.     bne.s    _do_inputstrfromfile      ; if file handle is used -> continue.
  643.  
  644.     move.b    #0,(a0)
  645.     move.l    #BFN,_error_code
  646.     rts                ; return NULL string.
  647.  
  648. _do_inputstrfromfile:
  649.     ; call fgetchars() -- (see fgets.c)
  650.     move.l    (a3),-(sp)        ; push the filehandle.
  651.     move.l    d1,-(sp)        ; push max_chars to read.
  652.     move.l    a0,-(sp)        ; push buffer address.
  653.     jsr    _fgetchars        ; returns X chars or NULL string.
  654.     add.l    #12,sp
  655.     jsr    _IoErr_poll
  656.  
  657.     move.l    #_fileinpstring,d0
  658.  
  659.     rts
  660.  
  661. ;
  662. ; LINE INPUT #filenumber;string-variable - read a line from filenumber'th file. 
  663. ;                     - d0=filenumber, a0=string-variable.
  664. ;
  665. _line_input:
  666.     ; legal file number?
  667.     jsr    _gencheckfilenum
  668.     cmpi.l    #-1,d0
  669.     bne.s    _line_input_get_handle
  670.  
  671.     move.b    #0,(a0)
  672.     rts                ; return NULL string.
  673.  
  674. _line_input_get_handle:
  675.     lsl.l    #2,d0            ; filenumber x 4.        
  676.     move.l    #_file_handle_list,d4
  677.     add.l    d0,d4             ; find start of long in list.
  678.     move.l    d4,a3
  679.     cmpi.l    #0,(a3)
  680.     bne.s    _do_line_input      ; if file handle is used -> continue.
  681.  
  682.     move.b    #0,(a0)
  683.     move.l    #BFN,_error_code
  684.     rts                ; return NULL string.
  685.  
  686. _do_line_input:
  687.     ; call fgetline() -- (see fgets.c)
  688.     move.l    (a3),-(sp)        ; push the filehandle.
  689.     move.l    #MAXSTRINGSIZE,-(sp)    ; want to read MAXSTRINGSIZE-1 chars. 
  690.     move.l    a0,-(sp)        ; push buffer address.
  691.     jsr    _fgetline        ; returns line of chars or NULL string.
  692.     add.l    #12,sp
  693.     jsr    _IoErr_poll
  694.     rts
  695.  
  696. ;
  697. ; INPUT# - input a string from a file. d0=filenumber; a0=temporary string.
  698. ;
  699. _finputstring:
  700.     ; store string address.
  701.     move.l    a0,-(sp)
  702.  
  703.     ; legal file number?
  704.     jsr    _gencheckfilenum
  705.     cmpi.l    #-1,d0
  706.     bne.s    _finputstring_get_handle
  707.  
  708.     move.b    #0,(a0)
  709.     addq    #4,sp            ; pop string address
  710.     rts                ; return NULL string.
  711.  
  712. _finputstring_get_handle:
  713.     lsl.l    #2,d0            ; filenumber x 4.        
  714.     move.l    #_file_handle_list,d4
  715.     add.l    d0,d4             ; find start of long in list.
  716.     move.l    d4,a3
  717.     cmpi.l    #0,(a3)
  718.     bne.s    _do_finputstring      ; if file handle is used -> continue.
  719.  
  720.     move.b    #0,(a0)
  721.     addq    #4,sp            ; pop string address
  722.  
  723.     move.l    #BFN,_error_code
  724.     rts                ; return NULL string.
  725.  
  726. _do_finputstring:
  727.     move.l    (a3),-(sp)        ; push file handle.
  728.     move.l    #MAXSTRINGSIZE,-(sp)    ; want to read MAXSTRINGSIZE-1 chars.
  729.     move.l    a0,-(sp)        ; push temp string address.
  730.     jsr    _fgetseqfld        ; returns sequential field in string.
  731.     add.l    #12,sp            
  732.     jsr    _IoErr_poll
  733.     move.l    (sp)+,a0        ; return string start address.
  734.  
  735.     rts    
  736.  
  737. ;
  738. ; INPUT# - input a FFP value from a file. d0=filenumber; a0=temporary string.
  739. ;      - FFP value returned in d0.
  740. ;
  741. _finputsingle:
  742.     jsr    _finputstring
  743.     move.l    a0,-(sp)
  744.     jsr    _val
  745.     addq    #4,sp
  746.     rts
  747.     
  748. ;
  749. ; INPUT# - input a short integer from a file. d0=filenumber; a0=temp string.
  750. ;      - short integer value returned in d0.
  751. ;
  752. _finputshort:
  753.     jsr    _finputstring
  754.     move.l    a0,-(sp)
  755.     jsr    _short_from_string
  756.     addq    #4,sp
  757.     rts
  758.  
  759. ;
  760. ; INPUT# - input a long integer from a file. d0=filenumber; a0=temp string.
  761. ;      - long integer value returned in d0.
  762. ;
  763. _finputlong:
  764.     jsr    _finputstring
  765.     move.l    a0,-(sp)
  766.     jsr    _long_from_string
  767.     addq    #4,sp
  768.     rts
  769.  
  770. ;
  771. ; EOF(n) - d0=n=filenumber. returns -1 if EOF reached, and 0 if not (d0).
  772. ;
  773. _eoftest:
  774.     jsr    _gencheckfilenum
  775.     cmpi.l    #-1,d0
  776.     bne.s    _eof_get_handle
  777.     rts            ; return TRUE
  778.     
  779. _eof_get_handle:
  780.     lsl.l    #2,d0        ; filenumber x 4.        
  781.     move.l    #_file_handle_list,d4
  782.     add.l    d0,d4        ; find start of long in list
  783.     move.l    d4,a0
  784.     move.l    d4,_eofhandle    ; store file handle
  785.     cmpi.l    #0,(a0)
  786.     bne.s    _do_eof_test    ; if file handle is used -> continue
  787.  
  788.     moveq    #-1,d0        ; unused file number, so return TRUE
  789.     move.l    #BFN,_error_code
  790.     rts
  791.  
  792. _do_eof_test:
  793.     move.l     (a0),d1        ; file handle
  794.     move.l     #1,d2        ; seek 1 byte from...
  795.     move.l    #0,d3        ; current position
  796.     move.l    _DOSBase,a6
  797.     jsr    _LVOSeek(a6)
  798.  
  799.      cmpi.l    #-1,d0        ; -1 = seek error
  800.     bne.s    _lastfileposn    
  801.     
  802.     rts            ; return TRUE (EOF reached)
  803.  
  804. _lastfileposn:
  805.     ; return to pre-seek position
  806.     move.l    _eofhandle,a0
  807.     move.l     (a0),d1        ; file handle
  808.     move.l     #-1,d2        ; seek -1 bytes from...
  809.     move.l    #0,d3        ; current position
  810.     move.l    _DOSBase,a6
  811.     jsr    _LVOSeek(a6)
  812.     
  813.     moveq    #0,d0                 
  814.     rts            ; return FALSE
  815.  
  816. ;
  817. ; LOF(n) - returns the length of an opened file in d0. n=d0=file number. 
  818. ;
  819. _lof:
  820.     jsr    _gencheckfilenum
  821.     cmpi.l    #-1,d0
  822.     bne.s    _lof_get_handle
  823.     moveq    #0,d0
  824.     rts            ; return length of 0
  825.  
  826. _lof_get_handle:
  827.     lsl.l    #2,d0        ; filenumber x 4.            
  828.     move.l    #_file_handle_list,d4
  829.     add.l    d0,d4        ; find start of long in list
  830.     move.l    d4,a0
  831.     cmpi.l    #0,(a0)
  832.     bne.s    _get_lof    ; if file handle is used -> continue
  833.     moveq    #0,d0        ; unused file number, so return length=0.
  834.     move.l    #BFN,_error_code
  835.     rts
  836.  
  837. _get_lof:
  838.     move.l    (a0),_filehandle
  839.     movea.l    _DOSBase,a6
  840.  
  841.     ; seek 0 bytes from EOF
  842.     ; to get old position in file.
  843.     move.l    _filehandle,d1
  844.     moveq    #0,d2
  845.     move.l    #OFFSET_END,d3
  846.     jsr    _LVOSeek(a6)
  847.     move.l    d0,_oldfilepos    ; store file position before LOF(n) called.
  848.  
  849.     ; seek 0 bytes from EOF again
  850.     ; because the first time the old 
  851.     ; position was returned. 
  852.     move.l    _filehandle,d1
  853.     moveq    #0,d2
  854.     move.l    #OFFSET_END,d3
  855.     jsr    _LVOSeek(a6)
  856.     move.l    d0,_filesize    ; store the file length.
  857.  
  858.     ; now return to the position
  859.     ; in the file prior to the above
  860.     ; two seeks.
  861.     move.l    _filehandle,d1
  862.     move.l    _oldfilepos,d2
  863.     move.l    #OFFSET_BEGINNING,d3
  864.     jsr    _LVOSeek(a6)
  865.  
  866.     move.l    _filesize,d0    ; return length of file in d0.
  867.  
  868.     rts
  869.     
  870. ;
  871. ; HANDLE(n) - returns the file handle of the nth file number. d0=n.
  872. ;
  873. _handle:
  874.     jsr    _gencheckfilenum
  875.     cmpi.l    #-1,d0
  876.     bne.s    _retrieve_handle
  877.     moveq    #0,d0
  878.     rts            ; return 0
  879.  
  880. _retrieve_handle:
  881.     lsl.l    #2,d0        ; filenumber x 4.        
  882.     move.l    #_file_handle_list,d4
  883.     add.l    d0,d4         ; find start of long in list
  884.     movea.l    d4,a0
  885.     move.l    (a0),d0        ; d0=filehandle
  886.  
  887.     rts
  888.  
  889. ;
  890. ; Check for legal filenumber.     Return -1 in d0 if not in range 0..254,
  891. ;                 otherwise just return filenumber.
  892. ;
  893. _gencheckfilenum:
  894.     subi.l    #1,d0        ; 1..255 -> 0..254
  895.  
  896.     ; check whether within bounds
  897.     cmpi.l    #0,d0
  898.     bge.s    _gencheckhifilenum
  899.     moveq    #-1,d0        ; return -1 for non-existent file.
  900.     move.l    #BFN,_error_code
  901.     rts            ; filenumber < 0? -> exit
  902.  
  903. _gencheckhifilenum:
  904.     cmpi.l    #254,d0
  905.     ble.s    _exitgencheckfilenum
  906.     moveq    #-1,d0        ; return -1 for non-existent file.
  907.     move.l    #BFN,_error_code
  908.  
  909. _exitgencheckfilenum:
  910.     rts            
  911.  
  912. ;
  913. ; KILL <filespec> - deletes file(s) or directory(ies).
  914. ;          - d1 = filespec.
  915. ;
  916. _kill:
  917.     movea.l    _DOSBase,a6
  918.     jsr    _LVODeleteFile(a6)
  919.     jsr    _IoErr_poll
  920.     rts
  921.  
  922. ;
  923. ; NAME <filespec1> AS <filespec2> - renames a file or directory.
  924. ;                  - d1 = filespec1, d2 = filespec2.
  925. ;
  926. _rename:
  927.     movea.l    _DOSBase,a6
  928.     jsr    _LVORename(a6)
  929.     jsr    _IoErr_poll
  930.     rts
  931.  
  932. ;
  933. ; CHDIR <dirname> - changes current directory to <dirname>.
  934. ;          - d1 = dirname.
  935. ;
  936. _chdir:
  937.     ; get a read lock on dirname (d1)
  938.     movea.l    _DOSBase,a6
  939.     move.l    #ACCESS_READ,d2
  940.     jsr    _LVOLock(a6)
  941.     jsr    _IoErr_poll
  942.  
  943.     tst.l    d0
  944.     beq.s    _quitchdir    ; quit if requested lock is zero
  945.  
  946.     ; change directory
  947.     move.l    d0,d1        ; pass lock in d1
  948.     jsr    _LVOCurrentDir(a6)
  949.  
  950.     tst.l    d0
  951.     beq.s    _quitchdir    ; quit if old lock is zero
  952.  
  953.     ; free old lock
  954.     move.l    d0,d1
  955.     jsr    _LVOUnLock(a6)
  956.  
  957. _quitchdir:        
  958.     rts
  959.  
  960.     END
  961.  
  962.